Adding A Model
MVC
Let's complete our saga into MVC by developing the M, which stands for model. This layer is all your business logic, queries, external dependencies, etc. of your application, which represents the problem to solve or the domain to solve.
This layer is controlled by WireBox, the dependency injection framework within ColdBox, which will give you the flexibility of wiring your objects and persisting them for you.
Let's create a simple contact listing, so open up CommandBox and issue the following command:
coldbox create service name="ContactService" methods="getAll" --open
This will create a
models/ContactService.cfc with a getAll() method and a companion unit test at tests/specs/unit/ContactServiceTest.cfc. Let's open the model object:/**
* I am a new Model Object
*/
component singleton accessors="true"{
// Properties
/**
* Constructor
*/
ContactService function init(){
return this;
}
/**
* getAll
*/
function getAll(){
}
}
Notice the
singleton annotation on the component tag. This tells WireBox that this service should be cached for the entire application lifespan. If you remove the annotation, then the service will become a transient object, which means that it will be re-created every time it is requested.Let's mock an array of contacts so we can display them later. We can move this to a SQL call later.
/**
* I am a new Model Object
*/
component singleton accessors="true"{
// Properties
property name="data" type="array";
/**
* Constructor
*/
ContactService function init(){
variables.data = [
{ "id"=1, "name"="coldbox" },
{ "id"=2, "name"="superman" },
{ "id"=3, "name"="batman" }
];
return this;
}
/**
* Get all the contacts
*/
function getAll(){
return variables.data;
}
}
We also have created a project to mock any type of data: MockDataCFC. Just use CommandBox to install it:
install mockdatacfcYou can then leverage it to mock your contacts or any simple/complex data requirement.
We have created our model, so let's tell our event handler about it. Let's create a new handler using CommandBox:
coldbox create handler name="contacts" actions="index" --open
This will create the
handler/contacts.cfc handler with an index() action, the views/contacts/index.cfm view and the accompanying integration test tests/specs/integration/contactsTest.cfc.Let's open the handler and add a new ColdFusion
property that will have a reference to our model object.component{
property name="contactService" inject="ContactService";
any function index( event, rc, prc ){
event.setView( "contacts/index" );
}
}
Please note that
inject annotation on the property definition. This tells WireBox what model to inject into the handler's variablesscope.By convention, it looks in the
models folder for the value, which in our case, is ContactService. Now let's call it and place some data in the private request collection prc so our views can use it.any function index( event, rc, prc ){
prc.aContacts = contactService.getAll();
event.setView( "contacts/index" );
}
Now that we have put the array of contacts into the
prc struct as aContacts, let's display it to the screen using ColdBox's HTML Helper.The ColdBox HTML Helper is a companion class in all layouts and views that allows you to generate semantic HTML without the needed verbosity of nesting or binding to ORM/Business objects.
Please check out the API Docs to discover the HTML Helper: http://apidocs.ortussolutions.com/coldbox/current/index.html?coldbox/system/modules/HTMLHelper/models/HTMLHelper.html
Open the
contacts/index.cfm and add the following to the view:<cfoutput>
<h1>My Contacts</h1>
#html.table( data=prc.aContacts, class="table table-striped" )#
</cfoutput>
Note: If your models are
singletons, they will persist for the lifespan of your ColdFusion application. To see code changes for singletons, you have to reinit the framework by using the ?fwreinit={password} Url action or via CommandBox using coldbox reinit. Please check out the API Docs to discover CommandBox: [https://apidocs.ortussolutions.com/commandbox/current/index.html]That's it! Execute the event:
http://localhost:{port}/contacts/index and view the nice table of contacts being presented to you.Congratulations, you have made a complete MVC circle!
Last modified 8d ago