1 of 6

Coding: Solo Style

Now that we have seen all the theory and stuff, let's get down to business and do some examples. We will start with the full coding approach with no ORM and then spice it up with ORM, so you can see how awesome ORM can be. The examples will not show the entire application being built, but enough to get you started with the process of modeling everything. Here is a layout of what we will build:

I will create a DAO for this small example, so we can showcase how to talk to multiple objects. You can start a new application with CommandBox if you like:

Datasource

Make sure you register a datasource in your ColdFusion administrator, we called ours contacts and then register it in your ColdBox configuration so ColdBox can build datasource structs for us. This is totally optional, but we do it to showcase more injections:

config/ColdBox.cfc

Contact.cfc

An object that represents a contact and self-validates using the cbvalidation module.

coldbox create model name=Contact --open

Then spice up with some properties and constraints:

component accessors="true"{

    // properties
    property name="firstName";
    property name="lastName";
    property name="email";

    // validation
    this.constraints = {
        firstName = {required=true},
        lastName = {required=true},
        email = {required=true, type="email"}
    };

    function init(){
        return this;
    }

}

ContactDAO.cfc

Our Contact DAO will talk to the datasource object we declared and do a few queries. Notice that this object is a singleton and has some dependency injection.

coldbox create model name=ContactDAO persistence=singleton --open

Then spice it up

component accessors="true" singleton{

    // Dependency Injection
    property name="dsn" inject="coldbox:setting:contacts";

    function init(){
        return this;
    }

    query function getAll(){
        var sql = "SELECT * FROM contacts";
        return queryExecute( sql, {}, { datasource: dsn.name } );
    }

    query function getContact(required contactID){
        var params = {
            contactID: { value: arguments.contactID, cfsqltype: "numeric" }
        };
        var sql = "SELECT * FROM contacts where contactID = :contactID";
        return queryExecute( sql, params, { datasource: dsn.name } );
    }

    ... ALL OTHER METHODS HERE FOR CRUD ....

}

ContactService.cfc

Here is our service layer and we have added some logging just for fun :). Notice that this object is a singleton and has some dependency injection.

Then spice it up

Now, some observations of the code:

We use the populator object that is included in WireBox to make our lives easier so we can populate objects from queries and deal with objects.
We also inject a reference to the object factory WireBox so it can create Contact objects for us. Why? Well what if those objects had dependencies as well.

Contacts Handler

Let's put all the layers together and make the handler talk to the model. I create different saving approaches, to showcase different integration techniques:

Spice it up now

Now that you have finished, go execute the contacts and interact with it.

Contact.cfc

An object that represents a contact and self-validates using the cbvalidation module.

coldbox create model name=Contact --open

Then spice up with some properties and constraints:

component accessors="true"{

    // properties
    property name="firstName";
    property name="lastName";
    property name="email";

    // validation
    this.constraints = {
        firstName = {required=true},
        lastName = {required=true},
        email = {required=true, type="email"}
    };

    function init(){
        return this;
    }

}

component accessors="true" singleton{

    // Dependency Injection
    property name="dao" inject="ContactDAO";
    property name="log" inject="logbox:logger:{this}";
    property name="populator" inject="wirebox:populator";
    property name="wirebox" inject="wirebox";

    function init(){
        return this;
    }

    /**
    * Get all contacts as an array of objects or query
    */
    function list(boolean asQuery=false){
        var q = dao.getAllUsers();
        log.info("Retrieved all contacts", q.recordcount);

        if( asQuery ){ return q; }

        // convert to objects
        var contacts = [];
        for(var x=1; x lte q.recordcount; x++){
            arrayAppend( contacts, populator.populateFromQuery( wirebox.getInstance("Contact"), q, x ) );
        }

        return contacts;
    }

    /**
    * Get a persisted contact by ID or new one if 0 or no records
    */
    function get(required contactID=0){
        var q = dao.getContact(arguments.contactID);
        // if 0 or no records
        if( contactID eq 0 OR q.recordcount eq 0 ){
            // return a new object
            return wirebox.getInstance("Contact");
        }
        // Else return the object
        return populator.populateFromQuery( wirebox.getInstance("Contact"), q, 1 );
    }

    ... ALL OTHER METHODS HERE  ....

}

component{

    // Dependency Injection
    property name="contactService" inject="ContactService";

    function index(event,rc,prc){
        // Get all contacts
        prc.aContacts = contactService.list();
        event.setView("contacts/index");
    }

    function newContact(event,rc,prc){
        event.setView("contacts/newContact");
    }

    function create(event,rc,prc){
        var contact = populateModel( "Contact" );
        // validate it
        var vResults = validateModel( contact );
        // Check it
        if( vResults.hasErrors() ){
            flash.put( "errors", vResults.getAllErrors() );
            return newContact(event,rc,prc);
        }
        else{
            flash.put( "notice", "Contact Created!" );
            setNextEvent("contacts");
        }
    }

    function save(event,rc,prc){
        event.paramValue("contactID",0);
        var contact = populateModel( contactService.get( rc.contactID ) );
        // validate it
        var vResults = validateModel( contact );
        // Check it
        if( vResults.hasErrors() ){
            flash.put( "errors", vResults.getAllErrors() );
            return newContact(event,rc,prc);
        }
        else{
            flash.put( "notice", "Contact Saved!" );
            setNextEvent("contacts");
        }
    }
}

ContactDAO.cfc

Our Contact DAO will talk to the datasource object we declared and do a few queries. Notice that this object is a singleton and has some dependency injection.

coldbox create model name=ContactDAO persistence=singleton --open

Then spice it up

component accessors="true" singleton{

    // Dependency Injection
    property name="dsn" inject="coldbox:setting:contacts";

    function init(){
        return this;
    }

    query function getAll(){
        var sql = "SELECT * FROM contacts";
        return queryExecute( sql, {}, { datasource: dsn.name } );
    }

    query function getContact(required contactID){
        var params = {
            contactID: { value: arguments.contactID, cfsqltype: "numeric" }
        };
        var sql = "SELECT * FROM contacts where contactID = :contactID";
        return queryExecute( sql, params, { datasource: dsn.name } );
    }

    ... ALL OTHER METHODS HERE FOR CRUD ....

}