> For the complete documentation index, see [llms.txt](https://coldbox.ortusbooks.com/llms.txt). Markdown versions of documentation pages are available by appending `.md` to page URLs; this page is available as [Markdown](https://coldbox.ortusbooks.com/the-basics/modules/module-async-scheduling.md).

# Module Async Scheduling

Define scheduled tasks for a module in its config/Scheduler.cfc configure() method.

Modules can easily tie in to [ColdBox Scheduled Tasks](/digging-deeper/scheduled-tasks.md#schedulers-for-modules) by defining a `config/Scheduler.cfc` file. This file only needs a `configure` method. Inside the file, you can define tasks to run asynchronously on a schedule and ColdBox will take care of the rest.

{% tabs %}
{% tab title="BoxLang" %}

```js
class {

    property name="settings" inject="coldbox:moduleSettings:unleashsdk";
    property name="log" inject="logbox:logger:{this}";

    function configure() {
        task( "unleashsdk-refresh-features" )
            .call( getInstance( "UnleashSDK@unleashsdk" ), "refreshFeatures" )
            .every( variables.settings.refreshInterval, "seconds" )
            .before( () => {
                if ( log.canDebug() ) {
                    log.debug( "Starting to fetch new features from Unleash" );
                } 
            } )
            .onSuccess( ( task, results ) => {
                if ( log.canInfo() ) {
                    log.info( "Successfully refreshed features", results );
                }
            } )
            .onFailure( ( task, exception ) => {
                if ( log.canError() ) {
                    log.error(
                        "Exception when running task [unleashsdk-refresh-features]:",
                        exception
                    );
                }
            } );

        task( "unleashsdk-send-metrics" )
            .call( getInstance( "UnleashSDK@unleashsdk" ), "sendMetrics" )
            .every( variables.settings.metricsInterval, "seconds" )
            .delay( variables.settings.metricsInterval, "seconds" )
            .before( () => {
                if ( log.canDebug() ) {
                    log.debug( "Starting to send metrics to Unleash" );
                } 
            } )
            .onSuccess( ( task, results ) => {
                if ( log.canInfo() ) {
                    log.info(
                        "Successfully sent metrics to Unleash features",
                        results
                    );
                }
            } )
            .onFailure( ( task, exception ) => {
                if ( log.canError() ) {
                    log.error(
                        "Exception when running task [unleashsdk-send-metrics]:",
                        exception
                    );
                }
            } );
    }

}
```

{% endtab %}

{% tab title="CFML" %}

```cfscript
component {

    property name="settings" inject="coldbox:moduleSettings:unleashsdk";
    property name="log" inject="logbox:logger:{this}";

    function configure() {
        task( "unleashsdk-refresh-features" )
            .call( getInstance( "UnleashSDK@unleashsdk" ), "refreshFeatures" )
            .every( variables.settings.refreshInterval, "seconds" )
            .before( function() {
                if ( log.canDebug() ) {
                    log.debug( "Starting to fetch new features from Unleash" );
                } 
            } )
            .onSuccess( function( task, results ) {
                if ( log.canInfo() ) {
                    log.info( "Successfully refreshed features", results );
                }
            } )
            .onFailure( function( task, exception ) {
                if ( log.canError() ) {
                    log.error(
                        "Exception when running task [unleashsdk-refresh-features]:",
                        exception
                    );
                }
            } );

        task( "unleashsdk-send-metrics" )
            .call( getInstance( "UnleashSDK@unleashsdk" ), "sendMetrics" )
            .every( variables.settings.metricsInterval, "seconds" )
            .delay( variables.settings.metricsInterval, "seconds" )
            .before( function() {
                if ( log.canDebug() ) {
                    log.debug( "Starting to send metrics to Unleash" );
                } 
            } )
            .onSuccess( function( task, results ) {
                if ( log.canInfo() ) {
                    log.info(
                        "Successfully sent metrics to Unleash features",
                        results
                    );
                }
            } )
            .onFailure( function( task, exception ) {
                if ( log.canError() ) {
                    log.error(
                        "Exception when running task [unleashsdk-send-metrics]:",
                        exception
                    );
                }
            } );
    }

}
```

{% endtab %}
{% endtabs %}


---

# Agent Instructions
This documentation is published with GitBook. GitBook is the documentation platform designed so that both humans and AI agents can read, navigate, and reason over technical content effectively. Learn more at gitbook.com.

## Querying This Documentation
If you need additional information that is not directly available in this page, you can query the documentation by asking a question.

Perform an HTTP GET request on the following URL with the `ask` and `goal` query parameters:

```
GET https://coldbox.ortusbooks.com/the-basics/modules/module-async-scheduling.md?ask=<question>&goal=<user_goal>
```

`ask` is the immediate question: it should be specific, self-contained, and written in natural language.
`goal` is what the user is ultimately trying to achieve, the reason they need the answer. Sharing it helps GitBook give you a better, more relevant answer. A goal is most helpful when it describes the outcome the user wants rather than restating the question. For example, with `ask=how do I create an API token`, a goal like `automate deployments from our CI pipeline` lets GitBook tailor the answer to that use case.

The response will contain a direct answer to the question and relevant excerpts and sources from the documentation.

Use this mechanism when the answer is not explicitly present in the current page, you need clarification or additional context, or you want to retrieve related documentation sections.